[C++] Restart program

woensdag 21 september 2005 @ 23:22:49 #26

vbmot

Are those my feet?

Windows machine+Simpele batchjob -> VBScript. Bagger syntax, maar idioot goed geïntegreerd in Windows. Juist voor dit soort zooi uitstekend geschikt.

Overigens mag je zelf wel even op zoek gaan. Ik zal je per onderdeel vast wat tips geven:
-File openen: FileSystemObject
-Text file doorzoeken: RegExp
-Programma stoppen: Kant en klare code via google te vinden
-Programma starten:

1 2	Set WshShell = WScript.CreateObject("WScript.Shell") WshShell.Run "programma.exe"

Looking for hotspots: wardriving or whoredriving?
Personal spam: http://www.kenya2ndhand.com

donderdag 22 september 2005 @ 16:37:51 #27

Xalopalyps

Thanks vmbot! Ik ga het eens proberen

ThanKs!

donderdag 22 september 2005 @ 18:20:50 #28

Xalopalyps

Het lukt goed, super thanks joh

donderdag 22 september 2005 @ 19:08:06 #29

fokME2

Post je source is dan 0=)

donderdag 22 september 2005 @ 19:59:33 #30

Xalopalyps

...vbs

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

' KillProg.vbs,  Version 1.01
' Kill a running program.
'
' Written by Rob van der Woude
' http://www.robvanderwoude.com

' Initialize variables
strMsg   = ""
numFound = 0

' Check command line parameters
Select Case WScript.Arguments.Count
        Case 0
                ' At least a process should be specified
                Syntax
        Case 1
                ' First parameter should be the process name
                ' or "/?" to request online help
                strP2k = Wscript.Arguments(0)
                if InStr( strP2k, "?" ) > 0 Then Syntax
                strComputer = "."
        Case 2
                ' First parameter should be the process name
                strP2k = Wscript.Arguments(0)
                if InStr( strP2k, "?" ) > 0 Then Syntax
                ' Second parameter should be a computer name
                strComputer = Wscript.Arguments(1)
                if InStr( strComputer, "?" ) > 0 Then Syntax
        Case Else
                ' Maximum is 2 command line parameter
                Syntax
End Select

On Error Resume Next
' Query and running processes
Set objWMIService = GetObject( "winmgmts://" & strComputer & "/root/cimv2" )
' Display error number and description if applicable
If Err.Number Then
        strMsg = vbCrLf & "Error # " & Err.Number & vbCrLf & _
                 Err.Description & vbCrLf & vbCrLf
        Syntax
End If
On Error GoTo 0
' Kill specified process
Set colItems = objWMIService.ExecQuery( "Select * from Win32_Process", , 48 )
For Each objItem in colItems
        If LCase( objItem.Caption ) = LCase( strP2k ) Then
                numFound = numFound + 1
                objItem.Terminate
        End If
Next

' Check if any process was found
If numFound = 0 Then
        WScript.Echo "No process named " & Chr(34) & strP2k & Chr(34) & " was found"
End If

' Done
WScript.Quit(0)

Sub Syntax
        strMsg = strMsg & vbCrLf & "KillProg.vbs,  Version 1.01" & vbCrLf & _
                 "Terminate (" & Chr(34) & "kill" & Chr(34) & _
                 ") a running program." & vbCrLf & vbCrLf & _
                 "Usage:  CSCRIPT  KILLPROG.VBS  prog_name  [ computer_name ]" & _
                 vbCrLf & vbCrLf & _
                 "Where:  " & Chr(34) & "prog_name" & Chr(34) & _
                 "     is the name of the program to be terminated" & vbCrLf & _
                 "        " & Chr(34) & "computer_name" & Chr(34) & _
                 " is the name of the computer where " & Chr(34) & _
                 "prog_name" & Chr(34) & " is" & vbCrLf & _
                 "                        to be terminated" & _
                 vbCrLf & vbCrLf & _
                 "Written by Rob van der Woude" & vbCrLf & _
                 "http://www.robvanderwoude.com" & vbCrLf
        WScript.Echo strMsg
        ' Abort with return code 1
        WScript.Quit(1)
End Sub

Die sluit een programma af, gevonden op internet, je roept hem aan met:

1	...vbs "naamvanprogramma.ext"

Programma starten is:

1 2	Set WshShell = WScript.CreateObject("WScript.Shell") WshShell.Run "programma.exe"

donderdag 22 september 2005 @ 20:40:17 #31

vbmot

Are those my feet?

Goed man! In C++ was die codelisting wel iets langer geweest

Looking for hotspots: wardriving or whoredriving?
Personal spam: http://www.kenya2ndhand.com

donderdag 22 september 2005 @ 21:52:59 #32

Xalopalyps

Kijk eens hoe vetjesss

*Trots is

Dit moet ik ook nog bij meer dingen maken, maar dit was ff om te proberen en het is perfect

En het mooie is, dat ik totaal geen poorten of iets dergelijks open heb moeten zetten op de server

Thanks voor jullie hulp

Forum Opties
Forumhop:
Hop naar:	(afkorting, bv 'KLB')

» digital corner

» digital corner